Tom's Guide > Forum > Programmation > [Résolu] Pièce jointe (VB6)

[Résolu] Pièce jointe (VB6)

Forum Programmation : [Résolu] Pièce jointe (VB6)

TomsGuide.com : 800 000 inscrits répondent à toutes vos questions high-tech et informatique. Pour obtenir de l'aide, inscrivez-vous gratuitement !

Créer un nouveau sujet Répondre

Bas de page Chercher dans ce sujet

Bonsoir ^^

J'aurais besoin de votre aide en ce qui concerne quelques trucs sur VB6.

Alors voilà, j'ai 2 questions concernant mon programme :

1.
J'ai une base de donnée "Etudiant.MDB" avec une table "ETUDIANT", "ETUDE", "ENSEIGNANT" et "DEPARTEMENT".
La table ETUDIANT a comme clé principale NUMETUDIANT. La table ETUDE a comme clé p. NUMETUDE et comme clé étrangère NUMETUDIANT. La table ENSEIGNANT quand à elle comporte comme c.p. "NUMENSEIGN" et comme c.e. "NUMETUDE".
Enfin, la table DEPARTEMENT a comme c.p. "NUMDEP" et comme clé étrangère "NUMENSEIGN".
Je voudrais savoir en fait le nombre d'étudiants (Nombre d'enregistrements de la table ETUDIANT) pour chaque departement.
Ex: J'ai un Form contenant une combobox, je sélectionne le numéro du département NUMDEP, et il me donne (en MsgBox ou dans un nouveau Form) le nombre d'étudiants de ce département.

2.
Est-ce possible de créer une interface graphique VB6 ou on pourrait parcourir les répertoires pour sélectionner un fichier ?
Un peu comme pour parcourir une pièce jointe sur les interfaces des boites mails ?
Je voudrais sélectionner une pièce jointe dans un formulaire, mais je ne trouve pas le bouton "Parcourir" dans la boite d'outils.

Si vous savez quoi que ce soit, n'hésitez pas à partager vos connaissances avec un débutant comme moi!
Merci d'avance pour toute aide et bonne soirée! ^.^

Message édité par love-ayu le 25-08-2009 à 19:12:34

Répondre

Inscrivez-vous ou connectez-vous pour masquer ceci.

Pour le point n°2, j'utilise un module qui me fourni des interfaces simplement !
Ca utilise les API de windows, ca marche sous win95, win98, win2000 et win XP sûr, j'ai pas testé sous les autres Windows.

Met ceci dans un module :

Code :

Option Explicit
Public Declare Function GetOpenFileName Lib "comdlg32.dll" Alias "GetOpenFileNameA" (pOpenfilename As OPENFILENAME) As Long
Public Declare Function GetSaveFileName Lib "comdlg32.dll" Alias "GetSaveFileNameA" (pOpenfilename As OPENFILENAME) As Long
Public Type OPENFILENAME
lStructSize As Long
hwndOwner As Long
hInstance As Long
lpstrFilter As String
lpstrCustomFilter As String
nMaxCustFilter As Long
nFilterIndex As Long
lpstrFile As String
nMaxFile As Long
lpstrFileTitle As String
nMaxFileTitle As Long
lpstrInitialDir As String
lpstrTitle As String
flags As Long
nFileOffset As Integer
nFileExtension As Integer
lpstrDefExt As String
lCustData As Long
lpfnHook As Long
lpTemplateName As String
End Type
Public Function OuvreChoixFichier() As String
Dim sRet As String
Dim of As OPENFILENAME
sRet = String(254, 0& )
of.flags = 4
of.hInstance = App.hInstance
of.lpstrInitialDir = "c:\"
of.lpstrTitle = "Charger un fichier"
of.hwndOwner = 0&
of.nFileExtension = 1
of.lpstrFile = sRet
of.nMaxFile = 254
of.lStructSize = Len(of)
of.lpstrFilter = "Fichier texte(*.text)" & vbNullChar & _
"*.txt" & vbNullChar & _
"Tous les fichiers (*.*)" & vbNullChar & _
"*.*" & vbNullChar & vbNullChar
If GetOpenFileName(of) > 0 Then
OuvreChoixFichier = Left(of.lpstrFile, InStr(1, of.lpstrFile, Chr(0)) - 1)
End If
End Function
Public Function OuvreSauveFichier(sExt As String, Optional sChemin As String = vbNullString) As String
Dim sRet As String
Dim of As OPENFILENAME
sRet = String(254, 0& )
of.flags = 1
of.hInstance = App.hInstance
of.lpstrInitialDir = sChemin
of.lpstrTitle = "Enregistrer sous ..."
of.hwndOwner = 0&
of.nFileExtension = 1
of.lpstrFile = sRet
of.nMaxFile = 254
If sExt = "txt" Then
of.lpstrDefExt = "txt"
of.lpstrFilter = "fichier Texte (*.txt)" & vbNullChar & _
"*.txt" & vbNullChar & _
"Tous les fichiers (*.*)" & vbNullChar & _
"*.*" & vbNullChar & vbNullChar
Else
of.lpstrFilter = "Tous les fichiers (*.*)" & vbNullChar & _
"*.*" & vbNullChar & vbNullChar
End If
of.lStructSize = Len(of)
If GetSaveFileName(of) > 0 Then
OuvreSauveFichier = Left(of.lpstrFile, InStr(1, of.lpstrFile, Chr(0)) - 1)
End If
End Function
Public Function getRepertoire(Optional repertoireInit As String = "c:\" ) As String
Dim oShell As Object
Dim oFolder As Object
Dim oFolderItem As Object
Set oShell = CreateObject("Shell.Application" )
Set oFolder = oShell.BrowseForFolder(&H0&, "Choisir un répertoire", &H1&, repertoireInit)
If Not oFolder Is Nothing Then
Set oFolderItem = oFolder.Self
getRepertoire = oFolderItem.Path
End If
End Function

et ensuite, depuis n'importe où tu peux faire :

Code :

s = OuvreChoixFichier()
MsgBox (s)

et 's' contiendra le fichier choisi, ou sera vide si la personne a annuler

Code :

s = OuvreSauveFichier("txt" )
MsgBox (s)

et 's' contiendra le fichier choisi pour l'enregistrement, ou sera vide si la personne a annuler

Code :

s = getRepertoire()
MsgBox (s)

et 's' contiendra le répertoire sélectionné ou sera vide si la personne a annuler

Répondre à sylfeline

Merci bien, ton code est intéressant! ^^

C'est bon par rapport à la première question, j'ai trouvé =)

Message édité par love-ayu le 25-08-2009 à 19:11:20

Répondre à love-ayu

Créer un nouveau sujet Répondre

Tom's Guide > Forum > Programmation > [Résolu] Pièce jointe (VB6)

Aller à :

Aide |
Règles du forum

Il y a 2146 utilisateurs connus et inconnus. Pour voir la liste des connectés connus, cliquez ici.

Page générée en 0,365 secondes

Liens